ベースボール・BSOインジケータ XBEE対応機
きっかけ
ベースボール・BSOインジケータとは、アウトカウントやボールカウントの(BSO)表示のことです。
通常は、左手で持つ薄型で回転ダイヤル式が使われます。しかし、ワンプレー毎に操作が多く、大変です。
もっと、楽に操作できるインジケータを作りたいと考え、IchigoJamで作ってみました。
初めは、手元でインジケータを操作し、確認していました。
しかし、スコアやカウントが電子掲示板で表示される立派な野球場は少なく、
観戦者にも見えるように、手元で操作したインジケータを観戦者にも見せる通信BOXを作りました。
以外にも、一番よく見ているのは、観戦者、監督、選手よりも、主審でした。
システム概要図
主要部品
- リモコン部
部品 | 数 | 購入先 | 秋月電子の商品コード | 当時の値段 |
---|---|---|---|---|
IchigoJam | 1枚 | 秋月電子 | K-09420 | \1,620 |
ユニバーサル基板 | 1枚 | 秋月電子 | P-03229 | \60 |
タクトスイッチ(緑色) | 1個 | 秋月電子 | P-03651 | \10 |
タクトスイッチ(黄色) | 1個 | 秋月電子 | P-03650 | \10 |
タクトスイッチ(赤色) | 1個 | 秋月電子 | P-03646 | \10 |
抵抗(1M) | 4個 | 秋月電子 | R-25105 | (100個パック)\100 |
超高輝度3mmLED(緑色) | 3個 | 秋月電子 | P-06313 | (10個パック)\200 |
超高輝度3mmLED(黄色) | 2個 | 秋月電子 | P-07206 | (10個パック)\200 |
超高輝度3mmLED(赤色) | 2個 | 秋月電子 | P-04767 | (10個パック)\200 |
抵抗(68Ω) | 7個 | 秋月電子 | R-14290 | (100個パック)\100 |
3端子レギュレータ(3.3V0.5A) | 1個 | 秋月電子 | I-00538 | \100 |
xBEE用2.54mmピッチ変換基板 | 1枚 | 秋月電子 | P-05060 | \300 |
XBEEモジュール | 1枚 | 秋月電子 | M-10069 | \2,200 |
スペーサー(25mm) | 4個 | 秋月電子 | P-07571 | 4本x\45 |
プラスチックケース SW-85S | 1個 | 秋月電子 | P-12049 | \160 |
モバイルバッテリー | 1個 | ダイソー | - | \300 |
- 表示部
部品 | 数 | 購入先 | 秋月電子の商品コード | 当時の値段 |
---|---|---|---|---|
1WパワーLED(緑色) | 3個 | 秋月電子 | I-06769 | 3個x\200 |
1WパワーLED(黄色) | 2個 | 秋月電子 | I-06773 | 2個x\150 |
1WパワーLED(赤色) | 2個 | 秋月電子 | I-06768 | 2個x\150 |
パワーLED用レンズ | 7個 | 秋月電子 | P-04039 | 7個x\100 |
抵抗(10Ω) | 7個 | 秋月電子 | -(忘れた。1W流せるモノ) | -(忘れた) |
NPNトランジスタ2SC3225 | 7個 | 秋月電子 | -(忘れた。350mA流せるモノ) | -(忘れた) |
ユニバーサル基板(10cm X 15cm) | 1枚 | 秋月電子 | -(忘れた) | -(忘れた) |
xBEE用USBインターフェイスボード | 1枚 | 秋月電子 | K-06188 | \1,280 |
XBEEモジュール | 1枚 | 秋月電子 | M-10069 | \2,200 |
プラスチックケース SY-150G | 1個 | 秋月電子 | P-12054 | \800 |
モバイルバッテリー | 1個 | ダイソー | - | \300 |
回路図 及び、写真
①IchigoJam基板
・外部サイト参照IchigoJam回路図
・LED端子は、LED7として利用
・BTN端子は、SW1のスライドスイッチ経由にして、自動起動モードとプログラムモードの切り替えに利用
・PS2キーボードの5V電源を、XBEEモジュールの3.3V電源に利用
②リモコン操作部
・IchigoJam基板と同じ大きさのユニバーサル基盤1枚
・タクトスイッチ(B:緑色、S:黄色、O:赤色、戻す:黒色)各1個
・高輝度LED(B:緑色x3個、S:黄色x2個、O:赤色x2個)
③,④XBEEモジュール
・XBEEモジュールのUSB通信接続基盤1枚
・XBEEモジュールのピッチ変換基盤1枚
・API通信モードで通信を行う
⑤外部表示部
・1WパワーLED 計7個
・LED拡大レンズ 計7個
・トランジスタ 500mA 計7個
工夫したところ
・Ichigojamの仕様で、プログラムは1Kバイトを4面使うことが来ます。今回は、2面使いました。
注意:再現する場合、XBEE固有のモジュールIDを変更する必要があるので、2面の変更が必要です。
1面のプログラムは、PC用ソフトウェア TeraTermで書き込み可能です。
・XBEEのAPI通信モード用ファームフェア書き換え、API通信モードのコマンド作成に、DigiKeyが提供しているPC用ソフトウェア X-CTUをインストールする必要があります。
プログラム解説
・1面
110:ビデオ出力停止し、省電力モードにする
111-113:変数初期化 B,S,O(表示用)、C,T,P(バックアップ)、I(スイッチ番号)、J,K,L(チャタリングキャンセル用)
120-380:ループ処理
130:スイッチ番号初期化(スイッチ押下無し)
135-200:スイッチ検出処理(3度読み)
210-360:スイッチ検出時の処理 Iが1ならBのカウント、Iが2ならSのカウント、Iが3ならOのカウント、Iが4ならバックアップのカウントに戻す
370:Iが0以外なら、20ms待って、Files1( 2面)のプログラムの3行目にジャンプしてXBEE送信処理
100 ' Titile: Score Boad
110 VIDEO 0
111 B=0:S=0:O=0
112 C=0:T=0:P=0
113 I=0:J=0:K=0:L=0
120 @LOOP
130 I=0
135 J=IN(1):K=IN(1):L=IN(1):J=J+K+L
140 IF 0=J THEN I=1
150 J=IN(2):K=IN(2):L=IN(2):J=J+K+L
160 IF 0=J THEN I=2
170 J=IN(3):K=IN(3):L=IN(3):J=J+K+L
180 IF 0=J THEN I=3
190 J=IN(4):K=IN(4):L=IN(4):J=J+K+L
200 IF 0=J THEN I=4
210 IF 1=I THEN C=B:B=B+1:T=S:P=O
220 IF 4=B THEN B=0:S=0
230 IF 2=I THEN T=S:S=S+1:C=B:P=O
240 IF 3=S THEN S=0:B=0:O=O+1
250 IF 3=I THEN P=O:O=O+1:C=B:T=S:'C=B:B=0:T=S:S=0
270 IF 3=O THEN O=0:B=0:S=0
275 IF 4=I THEN B=C:S=T:O=P
280 IF 0=B THEN OUT1,0:OUT2,0:OUT3,0
290 IF 1=B THEN OUT1,1:OUT2,0:OUT3,0
300 IF 2=B THEN OUT1,1:OUT2,1:OUT3,0
310 IF 3=B THEN OUT1,1:OUT2,1:OUT3,1
315 IF 0=S THEN OUT4,0:OUT5,0
320 IF 1=S THEN OUT4,1:OUT5,0
330 IF 2=S THEN OUT4,1:OUT5,1
340 IF 0=O THEN OUT6,0:OUT7,0
350 IF 1=O THEN OUT6,1:OUT7,0
360 IF 2=O THEN OUT6,1:OUT7,1
370 IF I <> 0 THEN WAIT 20:LRUN 1,3
380 GOTO @LOOP
・2面
1:APIコマンドの先頭の共通データを送信
3-12:APIコマンドの表示データを作成
13:APIコマンドの即時実行を要求(表示を直ぐに反映する)
15:Files0(1面)の380行目へジャンプして戻る
1 ? CHR$(#7E,#00,#10,#17,#01,#00,#13,#A2,#00,#40,#E4,#31,#28,#FF,#FE,#02,#44):RTN
3 IF 0=B THEN GSB 45:GSB 50:GSB 55
4 IF 1=B THEN GSB 30:GSB 50:GSB 55
5 IF 2=B THEN GSB 30:GSB 35:GSB 55
6 IF 3=B THEN GSB 30:GSB 35:GSB 40
7 IF 0=S THEN GSB 60:GSB 65
8 IF 1=S THEN GSB 70:GSB 65
9 IF 2=S THEN GSB 70:GSB 75
10 IF 0=O THEN GSB 80:GSB 85
11 IF 1=O THEN GSB 90:GSB 85
12 IF 2=O THEN GSB 90:GSB 95
13 ? CHR$(#7E,#00,#10,#17,#01,#00,#13,#A2,#00,#40,#E4,#31,#28,#FF,#FE,#02,#43,#4E,#25)
15 LRUN 0,380
30 GSB 1:? CHR$(#30,#04,#C8):RTN
35 GSB 1:? CHR$(#31,#04,#C7):RTN
40 GSB 1:? CHR$(#32,#04,#C6):RTN
45 GSB 1:? CHR$(#30,#05,#C7):RTN
50 GSB 1:? CHR$(#31,#05,#C6):RTN
55 GSB 1:? CHR$(#32,#05,#C5):RTN
60 GSB 1:? CHR$(#33,#04,#C5):RTN
65 GSB 1:? CHR$(#34,#04,#C4):RTN
70 GSB 1:? CHR$(#33,#05,#C4):RTN
75 GSB 1:? CHR$(#34,#05,#C3):RTN
80 GSB 1:? CHR$(#35,#04,#C3):RTN
85 GSB 1:? CHR$(#36,#04,#C2):RTN
90 GSB 1:? CHR$(#35,#05,#C2):RTN
95 GSB 1:? CHR$(#36,#05,#C1):RTN
まとめ
・1WパワーLEDと超高輝度LEDを使用しているため、真夏の炎天下でも利用可能です。
・小型なので、持ち運びに便利です。ただし、利用前日に、モバイルバッテリーの充電を忘れないでください。
・ZegBee通信なので、見通し100m程度の設置場所を自由に選択可能。主審から10メートル程度が理想的。
・モバイルバッテリーなので、2試合程度は使用可能。予備のモバイルバッテリーがあれば、安心です。
以上、同じものが欲しい方は、クラウドファンディングで協業しませんか。
投稿者の人気記事
-
kikuchim
さんが
2021/02/27
に
編集
をしました。
(メッセージ: 初版)
-
kikuchim
さんが
2021/02/27
に
編集
をしました。
-
kikuchim
さんが
2021/02/27
に
編集
をしました。
-
kikuchim
さんが
2021/02/27
に
編集
をしました。
-
kikuchim
さんが
2021/02/27
に
編集
をしました。
-
kikuchim
さんが
2021/02/28
に
編集
をしました。
-
kikuchim
さんが
2021/02/28
に
編集
をしました。
Opening
kaiapo
2023/11/09
ログインしてコメントを投稿する少年野球のコーチをしておりBSOインジケーターの自作を調べていてこちらにたどり着きました。とても素晴らしいですね!私自身電子工作の経験がなく、この様に作れるのはとても羨ましいです。
同じものが欲しければクラウドファンディングを、と書かれていましたが、実際お願い出来るものなのでしょうか。その場合おいくら位になりそうでしょうか。教えていただけますと幸いです。よろしくお願い致します。